资源文件

测试用例文件和测试套件初始化文件中的用户关键字和变量只能在创建它们的文件中使用，但是资源文件提供了一种 共享 它们的机制。

由于资源文件结构非常接近 测试用例 文件，因此创建它们很容易。

使用资源文件

使用 设置表 中的 资源设置 导入资源文件。资源文件的路径在设置名称后的单元格中给出。

*** Settings ***
Resource    example.resource
Resource    ../data/resources.robot
Resource    ${RESOURCES}/common.resource

资源文件的结构

资源文件的结构与 测试用例 文件的结构相同，但是，它们当然 不能包含测试用例表。

此外，资源文件中的设置表只能包含 导入设置（库，资源，变量）和文档。变量表和关键字表的使用方式与测试用例文件中使用的方式完全相同。

*** Settings ***
Documentation     An example resource file
Library           SeleniumLibrary
Resource          ${RESOURCES}/common.resource

*** Variables ***
${HOST}           localhost:7272
${LOGIN URL}      http://${HOST}/
${WELCOME URL}    http://${HOST}/welcome.html
${BROWSER}        Firefox

*** Keywords ***
Open Login Page
    [Documentation]    Opens browser to login page
    Open Browser    ${LOGIN URL}    ${BROWSER}
    Title Should Be    Login Page

Input Name
    [Arguments]    ${name}
    Input Text    username_field    ${name}

Input Password
    [Arguments]    ${password}
    Input Text    password_field    ${password}